Updates for Latvian (Windows)
Valdis Vītoliņš
valdis.vitolins at odo.lv
Thu May 27 12:32:44 EDT 2010
Thanks, Tao,
Attached files are what I see necessary:
1. doc/README-lv_LV.win32-bin.txt
2. Only part of packaging/win32/gnucash.iss.in
I have some doubts about code page. Windows default for Latvian is 1257,
and all other use single byte codepages.
Though for *po file I use UTF-8 which is default for Linux.
GUI labels etc. from *.po file for Windows build are OK,
so I assume it can handle UTF-8 also correctly
(which it should since NT 4.0, but you can never be sure about
Windows...
Or is there is some invisible code page conversion?)
Have somebody some thoughts/recommendations about this?
I assume, I will be able to get updated version for testing in
http://code.gnucash.org/builds/win32/trunk/
after it will be committed?
Valdis
> The following links should help:
>
> http://wiki.gnucash.org/wiki/Translation
> https://lists.gnucash.org/pipermail/gnucash-devel/2009-January/024535.html
> https://lists.gnucash.org/pipermail/gnucash-devel/2010-May/028335.html
>
> BTW, you can use TranslationProject to commit your translation for .po
> file. I didn't find 'lv' in gnucash domain on TP,
> http://translationproject.org/domain/gnucash.html, However, I found
> 'gnucash' in 'lv' team, http://translationproject.org/team/lv.html,
> which current status is "0 / 4061". To join the team, just sent an
> email to coordinator at translationproject.org, and after the approval,
> you can commit your translation to TP by email directly. I think it's
> a better way.
-------------- next part --------------
GnuCash ir bezmaksas grāmatvedības programma, ko izplata saskaņā ar
GNU General Public License (GPL) licenci. To var izmantot uz GNU/Linux,
*BSD, Solaris, Mac OSX un Microsoft Windows datoriem.
GnuCash ir veidots tā, lai to būtu vienkārši lietot, tajā pat laikā tas
ir pietiekami jaudīgs un ļauj uzskaitīt skaidru naudu, banku kontus,
akcijas, ieņēmumus un izdevumus.
Tajā var ātri un ērti reģistrēt darījumu, un tā ir balstīta uz
profesionālās grāmatvedības principiem, nodrošinot bilanci un
precīzus pārskatus.
-------------------
Tehniskā palīdzība
Tiešsaistes palīdzība: http://wiki.gnucash.org/wiki/FAQ
Vēstkopas: http://wiki.gnucash.org/wiki/Mailing_Lists
IRC (sazņa): #gnucash on server irc.gnome.org, skatīt arī http://wiki.gnucash.org/wiki/IRC
Ja atklājat kļūdas vai problēmas, nekautrējieties tās reģistrēt "Bugzilla" kļūdu apstrādes
sistēmā http://bugzilla.gnome.org/enter_bug.cgi?product=GnuCash
-------------------
Galvenās iespējas:
* Divkāršā ieraksta grāmatvedība
* Akciju/Vērtspapīru/Kapitāla daļu konti
* QIF/OFX datu imports
* OFX/HBCI tiešsaistes banka
* Pārskati, grafiki
* Mazo uzņēmumu biznesa atbalsts
* Klienti, Piegādātāji, Darbi, Saņemtie un izsniegtie rēķini
* Ieplānoti grāmatojumi
* Finanšu aprēķini
Vairāk informācijas un sākotnējā apmācība pieejama aktivizējot izvēlni
"Palīdzība" un "Pamācība un jēdzienu ceļvedis".
-------------------
Par šo programmu:
GnuCash ir bezmaksas grāmatvedības programma, ko izplata saskaņā ar
GNU General Public License (GPL) licenci. Tās galvenie izstrādātāji ir
12 cilvēki, kas sadarbojas ar atbalstītājiem vairāk kā 6 valstīs.
GnuCash izstrāde sākās 1997. gadā un tās pirmais laidiens bija 1998. gadā.
-------------------
Šis ir GnuCash 2.2.x README fails Windows binārajai pakotnei.
-------------- next part --------------
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Input configuration for the Inno Setup Compiler
; Copyright (c) 2004-2005 Christian Stimming <stimming at tuhh.de>
;
; Inno Setup Compiler: See http://www.jrsoftware.org/isdl.php
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[Setup]
; Using the name here directly because we want it capitalized
AppName=GnuCash
AppVerName=GnuCash @VERSION@
AppPublisher=GnuCash Development Team
AppPublisherURL=http://www.gnucash.org
AppSupportURL=http://www.gnucash.org
AppUpdatesURL=http://www.gnucash.org
VersionInfoVersion=@VERSION@
DefaultDirName={pf}\@PACKAGE@
DefaultGroupName=GnuCash
LicenseFile=@prefix@\..\dist\share\@PACKAGE@\doc\COPYING
Compression=lzma
MinVersion=5.0,5.0
PrivilegesRequired=poweruser
OutputDir=.
OutputBaseFilename=@PACKAGE at -@VERSION at -setup
UninstallFilesDir={app}\uninstall\@PACKAGE@
InfoAfterFile=@prefix@\..\dist\share\@PACKAGE@\doc\README.win32-bin.txt
SetupIconFile=@prefix@\..\dist\share\@PACKAGE@\pixmaps\gnucash-icon.ico
WizardSmallImageFile=@prefix@\..\dist\share\@PACKAGE@\pixmaps\gnucash-icon-48x48.bmp
[Types]
Name: "full"; Description: "{cm:FullInstall}"
Name: "custom"; Description: "{cm:CustomInstall}"; Flags: iscustom
[Components]
Name: "main"; Description: "{cm:MainFiles}"; Types: full custom; Flags: fixed
;Name: "translations"; Description: "{cm:TranslFiles}"; Types: full
;Name: "templates"; Description: "{cm:TemplFiles}"; Types: full
[Tasks]
Name: desktopicon; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"
Name: menuicon; Description: "{cm:CreateMenuLink}"; GroupDescription: "{cm:AdditionalIcons}"
[Icons]
Name: "{group}\GnuCash"; Filename: "{app}\bin\gnucash-bin.exe"; WorkingDir: "{app}\bin"; Comment: "{cm:IconComment_GnuCash}"; IconFilename: "{app}\share\gnucash\pixmaps\gnucash-icon.ico"; Tasks: menuicon; Flags: runminimized
Name: "{group}\{cm:IconName_README}"; Filename: "{app}\doc\gnucash\{cm:IconFilename_README}"; Comment: "{cm:IconComment_README}"; Tasks: menuicon
Name: "{group}\{cm:IconName_FAQ}"; Filename: "http://wiki.gnucash.org/wiki/FAQ"; Tasks: menuicon
Name: "{group}\{cm:IconName_Bugzilla}"; Filename: "http://bugzilla.gnome.org/enter_bug.cgi?product=GnuCash"; Tasks: menuicon
Name: "{group}\{cm:IconName_InstallFQ}"; Filename: "{app}\bin\install-fq-mods.cmd"; WorkingDir: "{app}\bin"; Comment: "{cm:IconComment_InstallFQ}"; Tasks: menuicon
Name: "{group}\{cm:IconName_Uninstall}"; Filename: "{uninstallexe}"; Comment: "{cm:IconComment_Uninstall}"; Tasks: menuicon
Name: "{commondesktop}\GnuCash"; Filename: "{app}\bin\gnucash-bin.exe"; WorkingDir: "{app}\bin"; Comment: "{cm:IconComment_GnuCash}"; IconFilename: "{app}\share\gnucash\pixmaps\gnucash-icon.ico"; Tasks: desktopicon; Flags: runminimized
[Run]
Filename: "{app}\bin\gnucash-bin.exe"; Description: "{cm:RunPrg}"; WorkingDir: "{app}\bin"; OnlyBelowVersion: 0,6; Flags: postinstall skipifsilent runhidden
Filename: "{app}\bin\guile.cmd"; Parameters: "-c ""(use-modules (ice-9 slib)) (require 'printf)"""; Flags: runhidden
;; The Windows firewall exceptions, see http://www.vincenzo.net/isxkb/index.php?title=Adding_a_rule_to_the_Windows_firewall
Filename: "{sys}\netsh.exe"; Parameters: "firewall add allowedprogram ""{app}\bin\gnucash-bin.exe"" ""GnuCash Free Finance Manager"" ENABLE ALL"; StatusMsg: "{cm:StatusMsgFirewall}"; Flags: runhidden; MinVersion: 0,5.01.2600sp2;
Filename: "{sys}\netsh.exe"; Parameters: "firewall add allowedprogram ""{app}\bin\gconfd-2.exe"" ""GConf Settings Manager"" ENABLE ALL"; StatusMsg: "{cm:StatusMsgFirewall}"; Flags: runhidden; MinVersion: 0,5.01.2600sp2;
[UninstallRun]
Filename: "{app}\bin\gconftool-2.exe"; Parameters: "--shutdown"; Flags: runhidden
Filename: "{sys}\netsh.exe"; Parameters: "firewall delete allowedprogram program=""{app}\bin\gnucash-bin.exe"""; Flags: runhidden; MinVersion: 0,5.01.2600sp2
Filename: "{sys}\netsh.exe"; Parameters: "firewall delete allowedprogram program=""{app}\bin\gconfd-2.exe"""; Flags: runhidden; MinVersion: 0,5.01.2600sp2
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Here we configure the included files and the place of their
; installation
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[Files]
; The main executables and DLLs
Source: "@prefix@\..\dist\bin\*"; DestDir: "{app}\bin"; Flags: recursesubdirs ignoreversion; Components: main; AfterInstall: MyAfterInstallConfig()
; Note: The above AfterInstall function will create the
; gnucash.cmd file on-the-fly by the Pascal script below.
Source: "@prefix@\..\dist\etc\*"; DestDir: "{app}\etc"; Flags: recursesubdirs; Components: main; AfterInstall: MyAfterInstallEtc()
Source: "@prefix@\..\dist\lib\*"; DestDir: "{app}\lib"; Flags: recursesubdirs; Components: main
Source: "@prefix@\..\dist\libexec\*"; DestDir: "{app}\libexec"; Flags: recursesubdirs; Components: main
Source: "@prefix@\..\dist\share\*"; DestDir: "{app}\share"; Flags: recursesubdirs; Components: main
; Additionally, we ship the Qt DLLs because the Online-Banking-Wizard
; lib/aqbanking/plugins/@-aqbanking_so_effective-@/wizards/qt3-wizard.exe needs them.
Source: "@-qtbindir-@\QtCore4.dll"; DestDir: "{app}\bin"; Flags: ignoreversion
Source: "@-qtbindir-@\QtGui4.dll"; DestDir: "{app}\bin"; Flags: ignoreversion
Source: "@-qtbindir-@\mingwm10.dll"; DestDir: "{app}\bin"; Flags: ignoreversion
; The following are all needed by Qt3Support
Source: "@-qtbindir-@\Qt3Support4.dll"; DestDir: "{app}\bin"; Flags: ignoreversion
Source: "@-qtbindir-@\QtXml4.dll"; DestDir: "{app}\bin"; Flags: ignoreversion
Source: "@-qtbindir-@\QtSql4.dll"; DestDir: "{app}\bin"; Flags: ignoreversion
Source: "@-qtbindir-@\QtNetwork4.dll"; DestDir: "{app}\bin"; Flags: ignoreversion
;; The translations
;Source: "@prefix@\..\dist\share\locale\*"; DestDir: "{app}\share\locale"; Flags: recursesubdirs; Components: translations
;
;; The account templates
;Source: "@prefix@\..\dist\share\gnucash\accounts\*"; DestDir: "{app}\share\gnucash\accounts"; Flags: recursesubdirs; Components: templates
; And all the documentation
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\README"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\README.win32-bin.txt"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\README-de.win32-bin.txt"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\README-fr.win32-bin.txt"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\README-it.win32-bin.txt"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\README-zh_CN.win32-bin.txt"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\COPYING"; DestDir: "{app}\doc\@PACKAGE@"; Flags: ignoreversion; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\AUTHORS"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
Source: "@prefix@\..\dist\share\@PACKAGE@\doc\ChangeLog"; DestDir: "{app}\doc\@PACKAGE@"; Components: main
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Define the registry keys Setup should create (HKLM = HKEY_LOCAL_MACHINE)
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[Registry]
Root: HKCR; Subkey: ".gnucash"; ValueType: string; ValueName: ""; ValueData: "GnuCash.Financial.Data"; Flags: uninsdeletevalue
Root: HKCR; Subkey: ".gnucash"; ValueType: string; ValueName: "Content Type"; ValueData: "application/x-gnucash"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "GnuCash.Financial.Data"; ValueType: string; ValueName: ""; ValueData: "GnuCash Financial Data"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "GnuCash.Financial.Data\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\share\gnucash\pixmaps\gnucash-icon.ico,0"
Root: HKCR; Subkey: "GnuCash.Financial.Data\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\bin\gnucash-bin.exe"" ""%1"""
Root: HKLM; Subkey: "Software\GnuCash"; ValueType: none; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\GnuCash\Paths"; ValueType: none; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\GnuCash\Paths"; ValueType: string; ValueName: "prefix"; ValueData: "{app}"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\GnuCash"; ValueType: string; ValueName: "InstallationDirectory"; ValueData: "{app}"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\GnuCash\Paths"; ValueType: string; ValueName: "libdir"; ValueData: "{app}\lib"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\GnuCash\Paths"; ValueType: string; ValueName: "pkglibdir"; ValueData: "{app}\lib\@PACKAGE@"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\GnuCash\Paths"; ValueType: string; ValueName: "sysconfdir"; ValueData: "{app}\etc"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\GnuCash\Paths"; ValueType: string; ValueName: "localedir"; ValueData: "{app}\share\locale"; Flags: uninsdeletevalue
; Additionally, we have to install the paths for gwenhywfar
Root: HKLM; Subkey: "Software\Gwenhywfar"; ValueType: none; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\Gwenhywfar\Paths"; ValueType: none; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\Gwenhywfar\Paths"; ValueType: string; ValueName: "prefix"; ValueData: "{app}"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Gwenhywfar\Paths"; ValueType: string; ValueName: "libdir"; ValueData: "{app}\lib"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Gwenhywfar\Paths"; ValueType: string; ValueName: "plugindir"; ValueData: "{app}\lib\gwenhywfar\plugins\@-gwenhywfar_so_effective-@"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Gwenhywfar\Paths"; ValueType: string; ValueName: "sysconfdir"; ValueData: "{app}\etc"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Gwenhywfar\Paths"; ValueType: string; ValueName: "localedir"; ValueData: "{app}\share\locale"; Flags: uninsdeletevalue
; And we also need some registry keys for aqbanking
Root: HKLM; Subkey: "Software\Aqbanking"; ValueType: none; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: none; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: string; ValueName: "providerdir"; ValueData: "{app}\lib\aqbanking\plugins\@-aqbanking_so_effective-@\providers"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: string; ValueName: "bankinfodir"; ValueData: "{app}\lib\aqbanking\plugins\@-aqbanking_so_effective-@\bankinfo"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: string; ValueName: "importerdir"; ValueData: "{app}\lib\aqbanking\plugins\@-aqbanking_so_effective-@\imexporters"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: string; ValueName: "wizarddir"; ValueData: "{app}\lib\aqbanking\plugins\@-aqbanking_so_effective-@\wizards"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: string; ValueName: "pkgdatadir"; ValueData: "{app}\share\aqbanking"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: string; ValueName: "sysconfdir"; ValueData: "{app}\etc"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\Aqbanking\Paths"; ValueType: string; ValueName: "localedir"; ValueData: "{app}\share\locale"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\AqBanking\Paths"; ValueType: string; ValueName: "xmldatadir"; ValueData: "{app}\share\aqhbci\xml"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\AqBanking\Paths"; ValueType: string; ValueName: "cfgmoduledir"; ValueData: "{app}\lib\aqbanking\plugins\@-aqbanking_so_effective-@\frontends\qbanking\cfgmodules"; Flags: uninsdeletevalue
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Delete the created config script on uninstall
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[UninstallDelete]
Type: files; Name: "{app}\bin\gnucash.cmd"
Type: files; Name: "{app}\bin\guile.cmd"
Type: files; Name: "{app}\etc\gnucash\environment"
Type: files; Name: "{app}\share\guile\1.6\slibcat"
Type: filesandordirs; Name: "{app}\share\guile"
Type: filesandordirs; Name: "{app}\etc\gconf"
Type: dirifempty; Name: "{app}\etc\gnucash"
Type: dirifempty; Name: "{app}\etc"
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; This large section is a Pascal scripting program that will modify
; the gnucash shell script so that it then includes the
; correct values according to our local installation. See
; http://www.remobjects.com/?ps for a syntax reference.
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[Code]
function MingwBacksl(const S: String): String;
begin
{ Modify the path name S so that it can be used by MinGW }
if Length(ExtractFileDrive(S)) = 0 then
Result := S
else begin
Result := '/'+S;
StringChange(Result, ':\', '\');
end;
StringChange(Result, '\', '/');
end;
procedure MyAfterInstallConfig();
var
FileName, FileString, appdir, libdir, pkglibdir, pkgdatadir: String;
Res: Boolean;
begin
{ Get the installation-specific paths }
appdir := ExpandConstant('{app}');
libdir := appdir + '\lib';
pkglibdir := libdir + '\gnucash';
pkgdatadir := appdir + '\share\gnucash';
{ Create the gnucash.cmd file; #10 is the linefeed character and #13 CR }
{ If you make any changes here, you should probably also change the equivalent sections }
{ in packaging/win32/install.sh, src/bin/environment*.in and src/bin/gnucash-setup-env-osx.in }
FileName := appdir + '\bin\gnucash.cmd' ;
FileString := 'setlocal'#13#10 ;
FileString := FileString + 'chcp ' + ExpandConstant('{cm:LanguageCodePage}') + ''#13#10 ;
FileString := FileString + 'set PATH=' + appdir + '\bin;' + libdir + ';' + libdir + '\gnucash;%PATH%'#13#10 ;
FileString := FileString + 'set GUILE_WARN_DEPRECATED=no'#13#10 ;
FileString := FileString + 'set GNC_MODULE_PATH=' + pkglibdir + ''#13#10 ;
FileString := FileString + 'set GUILE_LOAD_PATH=' + pkgdatadir + '\guile-modules;' + pkgdatadir + '\scm;' + appdir + '\share\guile\1.6;%GUILE_LOAD_PATH%'#13#10 ;
FileString := FileString + 'set LTDL_LIBRARY_PATH=' + libdir + ''#13#10 ;
FileString := FileString + 'set QOF_LIB_DIR=' + pkglibdir + ''#13#10 ;
FileString := FileString + 'set GNC_DBD_DIR=' + libdir + '\dbd'#13#10 ;
FileString := FileString + 'set GNC_STANDARD_REPORTS_DIR=' + pkgdatadir + '\guile-modules\gnucash\report\standard-reports'#13#10 ;
FileString := FileString + 'set SCHEME_LIBRARY_PATH='#13#10 ;
FileString := FileString + 'start gnucash-bin %*'#13#10 ;
{ Save the final file }
Res := SaveStringToFile(FileName, FileString, False);
if Res = False then
MsgBox('Error on saving '+FileName+' for completing the installation', mbInformation, MB_OK);
FileName := appdir + '\bin\guile.cmd' ;
FileString := 'set GUILE_LOAD_PATH=' + pkgdatadir + '\guile-modules;' + pkgdatadir + '\scm;' + appdir + '\share\guile\1.6;%GUILE_LOAD_PATH%'#13#10 ;
FileString := FileString + 'start guile.exe %*'#13#10 ;
Res := SaveStringToFile(FileName, FileString, False);
if Res = False then
MsgBox('Error on saving '+FileName+' for completing the installation', mbInformation, MB_OK);
end;
function BackslashPath(const S: String): String;
begin
{ Convert c:\soft to c:/soft }
Result := S;
StringChange(Result, '\', '/');
end;
procedure MyAfterInstallEtc();
var
FileName, FileString, appdir, libdir, pkglibdir, pkgdatadir: String;
Res: Boolean;
begin
{ Get the installation-specific paths }
appdir := BackslashPath( ExpandConstant('{app}') );
libdir := BackslashPath( appdir + '/lib' );
pkglibdir := BackslashPath( appdir + '/bin' );
pkgdatadir := BackslashPath( appdir + '/share/gnucash' );
{ Create the etc/gnucash/environment file; #10 is the linefeed character and #13 CR }
{ If you make any changes here, you should probably also change the equivalent sections }
{ in packaging/win32/install.sh, src/bin/environment*.in and src/bin/gnucash-setup-env-osx.in }
FileName := appdir + '\etc\gnucash\environment' ;
FileString := '# environment'#13#10 ;
FileString := FileString + '#'#13#10 ;
FileString := FileString + '# This configuration file can be used to change/add'#13#10 ;
FileString := FileString + '# environment variables during GnuCash startup.'#13#10 ;
FileString := FileString + '#'#13#10 ;
FileString := FileString + '[Variables]'#13#10 ;
FileString := FileString + 'PATH=' + appdir + '/bin;' + libdir + ';' + pkglibdir + ';{PATH}'#13#10 ;
FileString := FileString + 'SCHEME_LIBRARY_PATH='#13#10 ;
FileString := FileString + 'GNC_MODULE_PATH=' + pkglibdir + ''#13#10 ;
FileString := FileString + 'GUILE_LOAD_PATH=' + pkgdatadir + '/guile-modules;' + pkgdatadir + '/scm;' + appdir + '/share/guile/1.6;{GUILE_LOAD_PATH}'#13#10 ;
FileString := FileString + 'EXTRA_LIBS={GNC_MODULE_PATH}'#13#10 ;
FileString := FileString + 'LD_LIBRARY_PATH={EXTRA_LIBS};{LD_LIBRARY_PATH}'#13#10 ;
FileString := FileString + 'DYLD_LIBRARY_PATH={EXTRA_LIBS};{DYLD_LIBRARY_PATH}'#13#10 ;
FileString := FileString + 'LTDL_LIBRARY_PATH=' + libdir + ''#13#10 ;
FileString := FileString + 'QOF_LIB_DIR=' + pkglibdir + ''#13#10 ;
FileString := FileString + 'GNC_DBD_DIR=' + libdir + '/dbd'#13#10 ;
FileString := FileString + 'GNC_STANDARD_REPORTS_DIR=' + pkgdatadir + '/guile-modules/gnucash/report/standard-reports'#13#10 ;
FileString := FileString + 'GUILE_WARN_DEPRECATED=no'#13#10 ;
{ Save the final file }
Res := ForceDirectories(appdir + '\etc\gnucash');
if Res = False then
MsgBox('Error on creating '+appdir+'\etc\gnucash for completing the installation', mbInformation, MB_OK);
Res := SaveStringToFile(FileName, FileString, False);
if Res = False then
MsgBox('Error on saving '+FileName+' for completing the installation', mbInformation, MB_OK);
end;
[Languages]
Name: "en"; MessagesFile: "compiler:Default.isl"
Name: "de"; MessagesFile: "compiler:Languages\German.isl"; InfoAfterFile: "@prefix@\share\@PACKAGE@\doc\README-de.win32-bin.txt"
Name: "el"; MessagesFile: "@prefix@\share\@PACKAGE@\Greek-4-5.1.11.isl"
Name: "fr"; MessagesFile: "compiler:Languages\French.isl"; InfoAfterFile: "@prefix@\share\@PACKAGE@\doc\README-fr.win32-bin.txt"
Name: "it"; MessagesFile: "compiler:Languages\Italian.isl"; InfoAfterFile: "@prefix@\share\@PACKAGE@\doc\README-it.win32-bin.txt"
Name: "ja"; MessagesFile: "@prefix@\share\@PACKAGE@\Japanese-5-5.1.11.isl"
Name: "nl"; MessagesFile: "compiler:Languages\Dutch.isl"; InfoAfterFile: "@prefix@\share\@PACKAGE@\doc\README-nl.win32-bin.txt"
Name: "pt_BR"; MessagesFile: "compiler:Languages\BrazilianPortuguese.isl"
Name: "zh_CN"; MessagesFile: "@prefix@\share\@PACKAGE@\ChineseSimp-12-5.1.11.isl"; InfoAfterFile: "@prefix@\share\@PACKAGE@\doc\README-zh_CN.win32-bin.txt"
;; The following language files are available as well, in alphabetical
;; order: Basque, BrazilianPortuguese, Catalan, Czech, Danish, Dutch,
;; Finnish, Hungarian, Italian, Norwegian, Polish, Portuguese,
;; Russian, Slovak, Slovenian, Spanish
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; These are only for improved text messages
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[Messages]
[CustomMessages]
; *** "Select Components" wizard page
FullInstall=Full installation
CustomInstall=Custom installation
CreateDesktopIcon=Create a &desktop icon
CreateMenuLink=Create a start menu link
RunPrg=Run GnuCash now
AdditionalIcons=Create these icons:
StatusMsgFirewall=Installing Windows firewall rules...
MainFiles=GnuCash Program
TranslFiles=Translation Files
TemplFiles=Account Template Files
IconComment_GnuCash=GnuCash Free Finance Manager
IconName_README=Show README
IconComment_README=Show the README file
IconFilename_README=README.win32-bin.txt
IconName_FAQ=FAQ (Online)
IconName_Bugzilla=Report a Bug (Online)
IconName_InstallFQ=Install Online Price Retrieval
IconComment_InstallFQ=Install the necessary perl module Finance-Quote for online retrieval of prices. Requires ActivePerl 5.8 or 5.10
IconName_Uninstall=Uninstall GnuCash
IconComment_Uninstall=Uninstall the Finance Manager GnuCash
;; List of Code pages, used in gnucash.cmd
LanguageCodePage=1252
de.LanguageCodePage=1252
el.LanguageCodePage=1253
fr.LanguageCodePage=1252
it.LanguageCodePage=1252
ja.LanguageCodePage=932
nl.LanguageCodePage=1252
pt_BR.LanguageCodePage=1252
zh_CN.LanguageCodePage=936
lv_LV.LanguageCodePage=UTF-8
;; ;;;;;;;;;;;;;;;;;;;;
;; German translation
de.FullInstall=Komplett-Installation
de.CustomInstall=Benutzerdefiniert
de.CreateDesktopIcon=Ein Icon auf dem Desktop erstellen
de.CreateMenuLink=Eine Verkn�pfung im Startmen� erstellen
de.RunPrg=GnuCash jetzt starten
de.AdditionalIcons=Folgende Icons erstellen:
de.StatusMsgFirewall=Ausnahmen f�r Windows-Firewall installieren...
de.MainFiles=GnuCash Hauptprogramm
de.TranslFiles=Deutsche �bersetzung
de.TemplFiles=Beispiel-Kontenrahmen
de.IconComment_GnuCash=GnuCash OpenSource-Finanzverwaltung
de.IconName_README=README anzeigen
de.IconComment_README=Die Informationsdatei (README) anzeigen
de.IconFilename_README=README-de.win32-bin.txt
de.IconName_FAQ=H�ufige Fragen (online, engl.)
de.IconName_Bugzilla=Fehlerbericht einsenden (online, engl.)
de.IconName_InstallFQ=Online Kursabruf installieren
de.IconComment_InstallFQ=Das zus�tzliche Modul Finance-Quote installieren, um online Aktien- und Devisenkurse abrufen zu k�nnen. Dazu ist das Programm ActivePerl 5.8 oder 5.10 erforderlich.
de.IconName_Uninstall=Deinstallieren von GnuCash
de.IconComment_Uninstall=Die OpenSource-Finanzverwaltung GnuCash wieder deinstallieren und vom Computer l�schen
;; ;;;;;;;;;;;;;;;;;;;
;; Greek translation
el.FullInstall=������ �����������
el.CustomInstall=������������� �����������
el.CreateDesktopIcon=���������� ���������� ���� ��������� ��������
el.CreateMenuLink=�������� ��� ����� ������
el.RunPrg=�������� ��� GnuCash ����
el.AdditionalIcons=���������� ����������:
el.StatusMsgFirewall=����������� ������� ��� �� ������ ���������� ��� Windows...
el.MainFiles=��������� GnuCash
el.TranslFiles=������ �����������
el.TemplFiles=������ �� ������� �����������
el.IconComment_GnuCash=GnuCash ��������� ����. �����������
el.IconName_README=�������� ��� README
el.IconComment_README=�������� ��� ������� README
el.IconFilename_README=README.win32-bin.txt
el.IconName_FAQ=������ ��������� (Online)
el.IconName_Bugzilla=������� ��������� (Online)
el.IconName_InstallFQ=����������� ����� ����� (online)
el.IconComment_InstallFQ=����������� ��� perl module Finance-Quote ��� ���� ����� online. ������� ActivePerl 5.8/5.10
el.IconName_Uninstall=������������� GnuCash
el.IconComment_Uninstall=������������� ��� ����������� ����������� GnuCash
;; ;;;;;;;;;;;;;;;;;;;;
;; French translation
fr.FullInstall=Installation compl�te
fr.CustomInstall=Installation personnalis�e
fr.CreateDesktopIcon=Cr�er un ic�ne sur le bureau
fr.CreateMenuLink=Cr�er un lien dans le menu de d�marrage
fr.RunPrg=D�marrer GnuCash maintenant
fr.AdditionalIcons=Cr�er les ic�nes suivants:
fr.StatusMsgFirewall=Installation des r�gles de pare-feu de Windows
fr.MainFiles=Programme GnuCash
fr.TranslFiles=Traduction fran�aise
fr.TemplFiles=Mod�le de plan comptable
fr.IconComment_GnuCash=GnuCash, le gestionnaire financier OpenSource
fr.IconName_README=Afficher le LISEZMOI
fr.IconComment_README=Afficher le fichier LISEZMOI
fr.IconFilename_README=README-fr.win32-bin.txt
fr.IconName_FAQ=FAQ (En ligne, en anglais)
fr.IconName_Bugzilla=Envoyer un rapport d'erreur (En ligne, en anglais)
fr.IconName_InstallFQ=Installer les quotations en ligne
fr.IconComment_InstallFQ=Installation du module Finance-Quote requis pour le t�l�chargement du cours des devises et actions. Le programme ActivePerl 5.8 ou 5.10 est aussi requis
fr.IconName_Uninstall=D�-installer GnuCash
fr.IconComment_Uninstall=D�sinstalle le gestionnaire financier GnuCash
;; ;;;;;;;;;;;;;;;;;;;;;
;; Italian translation
it.FullInstall=Installazione completa
it.CustomInstall=Installazione personalizzata
it.CreateDesktopIcon=Crea un'icona sul desktop
it.CreateMenuLink=Crea un collegamento nel menu "start"
it.RunPrg=Avvia GnuCash
it.AdditionalIcons=Crea queste icone:
it.StatusMsgFirewall=Installazione delle regole per il firewall di Windows...
it.MainFiles=File del programma GnuCash
it.TranslFiles=Traduzione Italiana
it.TemplFiles=Modelli di strutture dei conti
it.IconComment_GnuCash=GnuCash: gestore di finanze libero
it.IconName_README=Mostra il file LEGGIMI
it.IconComment_README=Mostra il file LEGGIMI
it.IconFilename_README=README-it.win32-bin.txt
it.IconName_FAQ=FAQ (online, in Inglese)
it.IconName_Bugzilla=Comunicare un bug (online, in Inglese)
it.IconName_InstallFQ=Installa la funzione di ricerca delle quotazioni online
it.IconComment_InstallFQ=Installa il modulo di perl Finance-Quote necessario per ricevere le quotazioni online. Richiede ActivePerl 5.8/5.10
it.IconName_Uninstall=Disinstalla GnuCash
it.IconComment_Uninstall=Disinstalla il programma di gestione delle finanze GnuCash
;; ;;;;;;;;;;;;;;;;;
;; Dutch translation
nl.FullInstall=Volledige installatie
nl.CustomInstall=Aangepaste installatiie
nl.CreateDesktopIcon=Een &bureablad icoon aanmaken
nl.CreateMenuLink=Een verwijzing in het start menu aanmaken
nl.RunPrg=GnuCash nu starten
nl.AdditionalIcons=Deze iconen aanmaken:
nl.StatusMsgFirewall=Windows firewall regels installeren...
nl.MainFiles=GnuCash Programma
nl.TranslFiles=Vertalingsbestanden
nl.TemplFiles=Grootboekrekeningssjablonen
nl.IconComment_GnuCash=GnuCash Vrij Financieel Beheer
nl.IconName_README=LEESMIJ Tonen
nl.IconComment_README=Het LEESMIJ bestand tonen
nl.IconFilename_README=README-nl.win32-bin.txt
nl.IconName_FAQ=FAQ (Online)
nl.IconName_Bugzilla=Een Bug Melden (Online)
nl.IconName_InstallFQ=Online Koersen Opvragen installeren
nl.IconComment_InstallFQ=De benodigde perl module Finance Quote om online koersen op te vragen installeren. Hiervoor is ActivePerl 5.8 of 5.10 nodig.
nl.IconName_Uninstall=GnuCash verwijderen
nl.IconComment_Uninstall=Het financieel beheersprogramma GnuCash verwijderen
;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Brazilian Portuguese translation
pt_BR.FullInstall=Instala��o Completa
pt_BR.CustomInstall=Instala��o Personalizada
pt_BR.CreateDesktopIcon=Criar um �cone na �rea de Trabalho
pt_BR.CreateMenuLink=Criar um link no menu Iniciar
pt_BR.RunPrg=Executar o GnuCash agora
pt_BR.AdditionalIcons=Criar estes �cones:
pt_BR.StatusMsgFirewall=Instalando as regras de firewall do Windows...
pt_BR.MainFiles=Programa GnuCash
pt_BR.TranslFiles=Tradu��o
pt_BR.TemplFiles=Modelos de Conta
pt_BR.IconComment_GnuCash=Gerenciador Financeiro Livre GnuCash
pt_BR.IconName_README=Mostrar LEIA-ME (README)
pt_BR.IconComment_README=Mostra o arquivo LEIA-ME (README)
pt_BR.IconFilename_README=LEIA-ME.win32-bin.txt
pt_BR.IconName_FAQ=Perguntas Freq�entes (online, ingl�s)
pt_BR.IconName_Bugzilla=Relatar um erro (online, ingl�s)
pt_BR.IconName_InstallFQ=Instalar a Consulta de Pre�os Online
pt_BR.IconComment_InstallFQ=Instala o m�dulo perl Finance-Quote, necess�rio para a busca de pre�os online. Requer ActivePerl 5.8/5.10.
pt_BR.IconName_Uninstall=Desinstalar o GnuCash
pt_BR.IconComment_Uninstall=Desinstala o Gerenciador Financeiro GnuCash
;; ;;;;;;;;;;;;;;;;;
;; Simplified Chinese translation
zh_CN.FullInstall=��ȫ��װ
zh_CN.CustomInstall=�Զ��尲װ
zh_CN.CreateDesktopIcon=��������ͼ��
zh_CN.CreateMenuLink=������ʼ�˵����
zh_CN.RunPrg=���ڿ�ʼ���� GnuCash
zh_CN.AdditionalIcons=������Щͼ��
zh_CN.StatusMsgFirewall=���ڰ�װ Windows ���ǽ����...
zh_CN.MainFiles=GnuCash ����
zh_CN.TranslFiles=�����ļ�
zh_CN.TemplFiles=���ƿ�Ŀģ���ļ�
zh_CN.IconComment_GnuCash=GnuCash ���Ѳ�������
zh_CN.IconName_README=��ʾ�����ļ�
zh_CN.IconComment_README=��ʾ�����ļ�
zh_CN.IconFilename_README=README-zh_CN.win32-bin.txt
zh_CN.IconName_FAQ=�������� (����)
zh_CN.IconName_Bugzilla=�������� Bug (����)
zh_CN.IconName_InstallFQ=��װ���۸���������
zh_CN.IconComment_InstallFQ=��װ���۸������������� Perl Finance-Quoteģ�顣��Ҫ ActivePerl 5.8 �� 5.10
zh_CN.IconName_Uninstall=� GnuCash
zh_CN.IconComment_Uninstall=ж�ز����������� GnuCash
;; ;;;;;;;;;;;;;;;;;;;;
;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Latvian translation
lv_LV.FullInstall=Pilna uzstādīšana
lv_LV.CustomInstall=Izvēles uzstādīšana
lv_LV.CreateDesktopIcon=Izveidot &darbvirsmas ikonu
lv_LV.CreateMenuLink=Izveidot starta izvēlnes saiti
lv_LV.RunPrg=Palaist GnuCash tagad
lv_LV.AdditionalIcons=Izveidot sekojošas ikonas:
lv_LV.StatusMsgFirewall=Uzstāda Windows ugunssienas likumus...
lv_LV.MainFiles=GnuCash Programma
lv_LV.TranslFiles=Tulkojumu faili
lv_LV.TemplFiles=Kontu sagatavju faili
lv_LV.IconComment_GnuCash=GnuCash grāmatvedības programma
lv_LV.IconName_README=Parādīt README
lv_LV.IconComment_README=Parāda README failu
lv_LV.IconFilename_README=README-lv_LV.win32-bin.txt
lv_LV.IconName_FAQ=BUJ (tiešsaistē)
lv_LV.IconName_Bugzilla=Ziņot par kļūdu (tiešsaistē)
lv_LV.IconName_InstallFQ=Uzstādīt tiešsaistes kursu iegūšanu
lv_LV.IconComment_InstallFQ=Uzstādīt nepieciešamos Perl moduļus valūtas kursu iegūšanai. Nepieciešams ActivePerl 5.8 vai 5.10
lv_LV.IconName_Uninstall=Noņemt GnuCash
lv_LV.IconComment_Uninstall=Noņemt GnuCash grāmatvedības programmu
More information about the gnucash-devel
mailing list